DGUI3D Alpha v.2.2.4 - Помощь

DGUI3D ALPHA v.2.2.4

DGUI3D Alpha - графический интерфейс для 3D игр сделанных на Blitz3D. Предназначен для создания индивидуальных GUI в вашей игре. Включены основные функции, с помощью которых вы без труда создадите шедевр.

Copyright Versus Reality studio 2007©

www.VsReality.3dn.ru


НОВОЕ В ВЕРСИИ 2.2.4:

Добавлены новые функции:

DCreateView.TView- создать вид

DSetView - установить фрейм для вида

DActiveView - проверка на активность вида

DSetActView - Показать\спрятать вид

DSmoothYRotateFrame - плавный поворот на заданный угол

Для работы с текстом под средством стандартных шрифтов или с помощью модуля FastText можно использовать следующие команды:

DText - создает текст

DClsText - удаляет текст

В звуках добавлены две новых категории: move и turn. Звук соответственно

при движении и вращении(DTurnFrame, DMoveFrame)


Для более удобной работы можно пользоваться утилитами специально сделанными для DGUI3D ALpha

1. Fontshop 1.1 - с помощью этой программы вы легко создадите желаемый битмап-шрифт.

2. DotFont 1.0 - утилита для конвертирования битмап-шрифта в битмап для гуи.

Сделана для удобства работы со шрифтами. Теперь с помощью программы FontShop вы можете создать любой шрифт, изменить как вам надо в любом граф. редакторе. И затем, сконвертировав свой шрифт в ДотФонте вы смело можете вставлять его в ГУИ.

Примечание: символ не должен выходить за рамки 32х32. Поэтому при редактирование ставьте сетку(например в фотошопе), чтобы видеть когда вы выходите за пределы дозволенного.

3. SoundList 1.0 - создание саунд-листов для DGUI3D. Позволит вам создавать,изменять саунд-листы без знания xml-кода.


Лицензия на использование и распространение

программного продукта "DGUI3D ALPHA"

1. Все авторские права на программный продукт "DGUI3D ALPHA" принадлежат только разработчикам - VsReality studio.

2. Автор оставляет за собой право отменить действие данной лицензии для любой из следующих версий "DGUI3D ALPHA".

3. Вы можете совершенно бесплатно использовать данный программный продукт в некоммерческих целях, в случае использования продукта в коммерческих проектах Вам необходимо приобрести лицензию у разработчика.

4. "DGUI3D ALPHA" ПОСТАВЛЯЕТСЯ ПО ПРИНЦИПУ "AS IS". НИКАКИХ ГАРАНТИЙ НЕ ПРИЛАГАЕТСЯ И НЕ ПРЕДУСМАТРИВАЕТСЯ. ВЫ ИСПОЛЬЗУЕТЕ ЭТО ПРОГРАММНОЕ ОБЕСПЕЧЕНИЕ НА СВОЙ РИСК. АВТОР НЕ БУДЕТ ОТВЕЧАТЬ НИ ЗА КАКИЕ ПОТЕРИ ИЛИ ИСКАЖЕНИЯ ДАННЫХ, ЛЮБУЮ УПУЩЕННУЮ ВЫГОДУ В ПРОЦЕССЕ ИСПОЛЬЗОВАНИЯ ИЛИ НЕПРАВИЛЬНОГО ИСПОЛЬЗОВАНИЯ ЭТОГО ПРОГРАММНОГО ОБЕСПЕЧЕНИЯ.

5. Вы не можете использовать, копировать, сдавать в наем или аренду, продавать, изменять, изучать код программы другими способами, передавать зарегистрированную программу или любые из ее составляющих, иначе, чем определено настоящим лицензионным соглашением. Любое такое нелегальное использование означает автоматическое и немедленное прекращение действия настоящего соглашения и может преследоваться по закону.

6. Установка и использование "DGUI3D ALPHA" означает, что вы понимаете положения настоящего лицензионного соглашения и согласны с ними.

С наилучшими пожеланиями, VsReality studio.


Прежде чем начинать непосредственно работать с самим интерфейсом, необходимо его инициализировать.

Пример

Include "D_GUI2.bb"

Graphics3D 800,600,32,2

SetBuffer BackBuffer()

ClearTextureFilters()

cam = CreateCamera()

InitGUI()

Repeat

RenderWorld()

Flip

Until KeyHit(1)

DFreeGUI()

End


InitGUI(cam% = 0, posx# = -10000,posy# = -10000,posz# = -10000 ,x% = 0,y% = 0,width% = 0,height% = 0)

cam - камера gui, если равна 0, значит камера автоматически создаться.

posx, posy, posz - позиция пивота камеры(лучше его убирать далеко за саму сцену)

x,y - положение gui, в координатах экрана.

width, height - ширина/высота экрана gui.

Инициализация gui.


GUItoFront()

Переносим камеру GUI на первый план, по отношению к пред идущей созданной камере (вызывать после создания основной камеры игры)


DFreeGUI%()

Удаляем GUI


Всё gui основано на работе через фреймы. Поэтому для начало определим что это такое.

Фрейм - это элементарный элемент гуи. Он представляет собой квад.

Фрейм - это так же меш, поэтому вы можете пользоваться любыми блитцевскими командами по работе с мешом (фреймом).

Команда DCreateFrame() - является внутренней. На ней основано всё. И желательно ее не использовать. Вместо нее используйте DCreateWindow().

Если же вы желаете написать свой собственный компонент гуи - то DCreateFrame() вам поможет(только осмотрите структуру типа TFrame).

Каждый фрейм может быть как анимированным, так и статическим.

Команды управления фреймом:

DSizeFrame ()

DPositionFrame ()

DActiveFrame()

DHideFrame ()

DShowFrame()

DParentFrame()

DColorFrame()

DAlphaFrame()

DUpdateFrame()

DMoveFrame()

DGetWidthFrame()

DGetHeightFrame()

DGetXFrame()

DGetYFrame()

DGetActiveFrame()

DGetOrderFrame()

DSetOrderFrame()

DOrderFrame()

DRotateFrame()

DTurnFrame()

DSmoothYRotateFrame()

DActiveBtn()


DCreateFrame.TFrame(width%,height%,image$="", frames=0)

width,height - габариты фрейма(в пикселах)

image - файл рисунка фрейма(можно анимированный)

frames - кол-во кадров анимированного рисунка

Возвращает объект фрем типа TFrame


DSizeFrame( frment, width#, height#)

frment - фрейм-меш

width, height - новые размеры

Установка размера фрейма


DPositionFrame( frment, x%, y%, centrovka = False)

frment - фрейм-меш

x, y - координаты положения на экране

centrovka - центровка(True\False). True - центр фрейма - его центр масс. False - левый верхний угол.

Установка положения фрема на экране


DActiveFrame(frment)

frment - фрейм-меш

Активировен ли фрейм(наведен ли курсор)

0 - неактивен

1 - наведен курсор


DHideFrame(frment,bool = True)

frment - фрейм-меш

bool - спрятать\показать

Спратать фрейм-меш


DShowFrame(frment,bool = True)

frment - фрейм-меш

bool - показать\спрятать

Показать фрейм-меш


DParentFrame(entfrm, parentfrm )

entfrm - фрейм-меш

parentfrm - родитель(тоже фрейм-меш)

Создание родителя


DColorFrame( entfrm, r%, g%, b% )

entfrm - фрейм-меш

r, g, b - цвет фрейма-меша(красный, зеленый, синий)

Установить цвет фрейма


DAlphaFrame( entfrm, alpha#)

entfrm - фрейм-меш

alpha - прозрачность(0.0 - 1.0)

Установить прозрачность фрейма-меша


DUpdateFrame(frment, speed% = 40)

frment - анимированный фрейм-меш

speed - скорость анимации

Обновление анимационного фрейма-меша, скорость от 1 до 100


DMoveFrame(frment, movex% =0, movey% =0)

frment - фрейм-меш

movex, movey -смещение фрема-меша по оси x и y

Смещение фрейма-меша на movex и movey


DOrderFrame(frm_ent,frm_down)

frm_ent - фрейм-меш, котрый должен быть над frm_down

frm_down - фрейм-меш, который должен быть за frm_ent

Установка видимости фремов. frm_ent становиться на передний план относительно frm_down.


DRotateFrame(frm_ent, rot#)

frm_ent - фрейм-меш

rot - угол поворота

Поворот фрейма-меша


DTurnFrame(frm_ent, drot#)

frm_ent - фрейм-меш

rot - относительный угол вращения(скорость вращения)

Вращение фрейма-меша


DSetOrderFrame(frm_ent,order%)

frm_ent - фрейм-меш

order - ордер

Установка конктретного ордера для фрейма-меша


DActiveBtn(act_txt, r1, g1, b1, r2, g2 ,b2)

act_txt - текст-фрейм

r1, g1, b1 - цвет неактивного текста

r2, g2 ,b2 - цвет при наведении курсора

Активность кнопки-текста


DGetWidthFrame(frm_ent)

frm_ent - фрейм-меш

Получить ширину фрейма-меша


DGetHeightFrame(frm_ent)

frm_ent - фрейм-меш

Получить высоту фрейма-меша


DGetXFrame(frm_ent)

frm_ent - фрейм-меш

Получить координату x фрейма-меша


DGetYFrame(frm_ent)

frm_ent - фрейм-меш

Получить координату y фрейма-меша


DGetActiveFrame(frm_ent)

frm_ent - фрейм-меш

Возвращает активен ли фрейм


DGetOrderFrame(frm_ent)

frm_ent - фрейм-меш

Возвращает ордер фрейма


DFreeFrame(frm_ent)

frm_ent - фрейм-меш

Удалить фрейм


DFreeAllFrame()

Удалить все фреймы


DSmoothYRotateFrame( frment, yaw# )

frm_ent - фрейм-меш

yaw - угол

Плавный поворот на заданный угол


Для работы с окнами-фреймами используется команда DCreateWindow()

Пример

; Подключаем ГУИ

Include "D_GUI2.bb"

Graphics3D 1024,768,32,2

SetBuffer BackBuffer()

SetFont LoadFont("Tahoma",16,True)

;Здесь необизательно, но иногда требуется, чтобы текстура была четкой

ClearTextureFilters()

;Создание сцены

light = CreateLight()

cam = CreateCamera()

;Инициализация ГУИ

InitGUI()

window = DCreateWindow(500,200,"skin.png")

;Создаем вид курсора - ширина, высота, файл анимации, кол-во кадров

Mouse = DCreateMouse(36,36,"images\Mouse.png",12)

;Изменяем размер курсора

DSizeFrame Mouse,18,18

HidePointer()

Repeat

;Аннимируем курсор

DUpdateFrame Mouse

;Перемещаем курсор

DPositionFrame Mouse,MouseX(),MouseY()

;Необходимо если используятся Button или TextBox

FlushKeys()

FlushMouse()

UpdateWorld

RenderWorld

Text 10,10,d

Flip

Until KeyHit(1)

;Удаляем ГУИ

DFreeGUI()

End


DCreateWindow%(width%,height%,image$)

width,height - габариты окна-фрейма

image - рисунок(скин окна)

Создает окно. Возвращает фрейм окна


Для работы с кнопками используются следующие функции:

DCreateButton() - создаётся фрейм-кнопка

DActiveButton() - проверка активности фрейм-кнопки

Пример

; Подключаем ГУИ

Include "D_GUI2.bb"

Graphics3D 1024,768,32,2

SetBuffer BackBuffer()

SetFont LoadFont("Tahoma",16,True)

;Здесь необизательно, но иногда требуется, чтобы текстура была четкой

ClearTextureFilters()

;Создание сцены

light = CreateLight()

cam = CreateCamera()

;Инициализация ГУИ

InitGUI()

DFont.TFont = DLoadFont("Images\Font.png")

;Пример с кнопкой

btn = DCreateButton(frm, 100,200,67,36,"images\Infobtn.png",2)

;Создаем вид курсора - ширина, высота, файл анимации, кол-во кадров

Mouse = DCreateMouse(36,36,"images\Mouse.png",12)

;Изменяем размер курсора

DSizeFrame Mouse,18,18

HidePointer()

Repeat

;Обновление кнопок

DActiveButton(btn)

;Аннимируем курсор

DUpdateFrame Mouse

;Перемещаем курсор

DPositionFrame Mouse,MouseX(),MouseY()

;Необходимо если используятся Button или TextBox

FlushKeys()

FlushMouse()

UpdateWorld

RenderWorld

Text 10,10,d

Flip

Until KeyHit(1)

;Удаляем ГУИ

DFreeGUI()

End


DCreateButton(parentent, x , y ,width%, height%, anim_image$, frames = 3)

parent_ent - родитель-фрейм

x , y - локальные координаты

width, height - габариные размеры кнопки(размеры вашего рисунка)

anim_image - файл анимированного рисунка(максимум 3 кадра)

frames - кадры анимированного рисунка

Создает фрейм-кнопку


DActiveButton(btnent)

btnent - фрейм-кнопка

Проверка активности кнопки.

Возвращает 0,1 или 2

0 - неактивна

1 - наведена мышь

2 - кнопка нажата


Для работой с текстом можно воспользоваться 2 способами, или их камбинировать как вам надо

1 способ: работа с динамическим текстом. Текст строится на базе вашего бит-мап шрифта(TFont):

DCreateText()

DUpdateText()

2 способ: только статический текст. Работает по аналогии с блитцевским текстом. Возможно использование библеотеки FastText:

DText()

DClsText()

Пример(способ 1)

; Подключаем ГУИ

Include "D_GUI2.bb"

Graphics3D 1024,768,32,2

SetBuffer BackBuffer()

SetFont LoadFont("Tahoma",16,True)

;Здесь необизательно, но иногда требуется, чтобы текстура была четкой

ClearTextureFilters()

;Создание сцены

light = CreateLight()

cam = CreateCamera()

;Назначаем камеру для ГУИ

InitGUI()

;Загружаем битовый шрифт(.png)

Fnt.TFont = DLoadFont("images\Font2.png")

;Текст

Txt = DCreateText(Fnt, 10,10, "Это пример текста. Чтобы писать с новой строки пишем знак |вот мы и спустились :-)||И еще спустилисъ", .6)

DColorFrame Txt,255,255,255

Repeat

;Необходимо если используятся Button или TextBox

FlushKeys()

FlushMouse()

UpdateWorld

RenderWorld

Flip

Until KeyHit(1)

;Удаляем ГУИ

DFreeGUI()

End

Пример(способ 1+ способ 2)

; Подключаем ГУИ

Include "D_GUI2.bb"

Graphics3D 1024,768,32,2

SetBuffer BackBuffer()

ClearTextureFilters()

Font=LoadFont("Tahoma",20)

Color 255,255,0

SetFont Font

;Создание сцены

light = CreateLight()

cam = CreateCamera()

CameraClsColor cam,100,100,100

InitGUI()

Fnt.TFont = DLoadFont("Images\Font2.png")

txt = DText(100,400,"This work of then memory bitle maze board case of change")

;DColorFrame txt,100,255,100

txt2 = DCreateText(Fnt,20,20,"Привет всем",1)

Mouse = DCreateMouse(36,36,"images\Mouse.png",12)

DSizeFrame Mouse,18,18

;

HidePointer()

Repeat

DActiveBtn(txt,50,50,50,0,0,0)

DActiveBtn(txt2,50,50,50,45,200,255)

DUpdateFrame Mouse

DPositionFrame Mouse,MouseX(),MouseY()

RenderWorld

Flip

Until KeyHit(1)

;Удаляем ГУИ

DFreeGUI()

End


DCreateText%(Font%,x%,y%,text$,scale#, frm_ent%)

Font - объект битмап-шрифта типа TFont

x,y - локальные координаты

text - текст

scale - масштаб текста

frm_ent - фрейм-родитель(может быть нулевым)

Создает текст из битмап-шрифта. Для создания многострочного текста используйте символ - |.

Например, text$ = "Это первая строка|Это вторая строка"


DUpdateText(txt_ent,text$)

txt_ent - обновляемый фрейм-текст

text$ - новый текст

Обновляет текст


DText(x%,y%,txt$)

x%,y% - экранные координаты текста

txt$ - текст

Создает текст. аналогия блитцевского текста(только через гуи). Можно использовать библеотеку FastText


DClsText(text_ent)

text_ent - фрейм-текст(DText)

Удаляет фрейм-текст(DText)


Для работы с редактируемым текстом применяются следующие функции:

DCreateEditBox() - создает редактируемый текст

DUpdateEditBox() - проверка ввода текста

DGetEditBox() - получение вводимого содержания

Он позволяет создавать поля для ввода данных.

Пример

; Подключаем ГУИ

Include "D_GUI2.bb"

Graphics3D 1024,768,32,2

SetBuffer BackBuffer()

SetFont LoadFont("Tahoma",16,True)

;Здесь необизательно, но иногда требуется, чтобы текстура была четкой

ClearTextureFilters()

;Создание сцены

light = CreateLight()

cam = CreateCamera()

;Назначаем камеру для ГУИ

InitGUI()

;Загружаем битовый шрифт(.png)

Fnt.TFont = DLoadFont("images\NewFont.png")

;

Win = DCreateWindow(520,60)

DPositionFrame Win,100,100

DColorFrame Win,100,45,100

;Текст пишется на определенном фрейме, поэтому мы и сделали фрейм Win

Txt = DCreateText(Fnt, -200,-25, "Пишем внизу, с наведенном на EditBox курсором", .6, Win)

DColorFrame Txt,255,255,255

;Создаем EditBox - редактируемый текст

EdBox = DCreateEditBox(Fnt,-200,-5,10,.7,Win)

DColorFrame EdBox,200,245,165

Repeat

;Проверяем, вводится ли текст

DUpdateEditBox EdBox

;Необходимо если используятся Button или TextBox

FlushKeys()

FlushMouse()

UpdateWorld

RenderWorld

;Выводим содержимое editbox'a

Text 10,60,"Ну вы попытались ввести что-то вроде этого: " + DGetEditBox(EdBox)

Flip

Until KeyHit(1)

;Удаляем ГУИ

DFreeGUI()

End


DCreateEditBox%(Font.TFont, x%, y%, maxlength%, scale#, frm_ent%)

Font - битмап-шрифт загруженный с помощью DLoadFont()

x, y -локальные координаты оедактируемого текста

maxlength - максимальное кол-во символов

scale# - масштаб вводимого текста

frm_ent% - фрейм-родитель

Создает объект вид(новое окно) типа TVeiw


DUpdateEditBox(edit_ent)

edit_ent - редактируемый текст

Обнавляет редактируемый текст(проверка на ввод текста)


DGetEditBox$(edit_ent)

edit_ent - редактируемый текст

Возвращает вводимый текст


Виды используются для построения более сложных конструкций интерфейса, например, создание меню с плавными переходами между видами(новые окна).

Вид(родитель) в себе может содержать нужное кол-во фреймов(детей).

Для создания вида используется команда DCreateView.TView().

Для крепления фрейма к виду используем DSetView().

Для проверки активности вида используем DActiveView().

Ну и, соответственно для установки активности вида используем DSetActView()

Пример

; Подключаем ГУИ

Include "D_GUI2.bb"

Graphics3D 1024,768,32,2

SetBuffer BackBuffer()

SetFont LoadFont("Tahoma",16,True)

;Здесь необизательно, но иногда требуется, чтобы текстура была четкой

ClearTextureFilters()

;Создание сцены

light = CreateLight()

cam = CreateCamera()

;Создаем анимированный курсор

;Назначаем камеру для ГУИ

InitGUI()

;Создаём два вида

;Вид - это самый главный объект гуи. Это нечто вроде нового экрана.

View1.TView = DCreateView(True) ;Так как значение установлено в True, значит этот вид является главным - он появится

;при запуске программы

win1 = DCreateWindow(100,100,"")

DPositionFrame win1,100,100,1

DSetView(win1, View1)

View2.TView = DCreateView()

win2= DCreateWindow(50,50,"")

DPositionFrame win2,300,300,1

DColorFrame(win2,255,0,0)

DSetView(win2, View2)

;Создаем вид курсора - ширина, высота, файл анимации, кол-во кадров

Mouse = DCreateMouse(36,36,"images\Mouse.png",12)

;Изменяем размер курсора

DSizeFrame Mouse,18,18

HidePointer()

Repeat

;Обновляем виды

DActiveView(View1)

DActiveView(View2)

;Переключаем вид1 на вид2

If MouseHit(1)

DSetActView(View1,False)

DSetActView(View2,True)

EndIf

;Переключаем вид2 на вид1

If MouseHit(2)

DSetActView(View1,True)

DSetActView(View2,False)

EndIf

;Аннимируем курсор

DUpdateFrame Mouse

;Перемещаем курсор

DPositionFrame Mouse,MouseX(),MouseY()

;Необходимо если используятся Button или TextBox

FlushKeys()

FlushMouse()

UpdateWorld

RenderWorld

Text 10,10,"ЛКМ - скрыть вид1, ПКМ - скрыть вид2"

Flip

Until KeyHit(1)

;Удаляем ГУИ

DFreeGUI()

End


DCreateView(main_view, start_alpha#)

main_view - False\True - указывает основной ли это вид(основной показывается сразу после компиляции программы.

start_alpha# - начальная прозрачность для вида(всех фреймов входящих в него).

Создает объект вид(новое окно) типа TVeiw


DSetView(frm_ent, view)

frm_ent - фрейм

view - объект вид

Прикрепляет фрейм к виду.


DActiveView(View, dalpha#)

View - объект вид

dalpha - скорость перехода одного вида в другой

Обновление вида


DSetActView(View, act)

View - объект вид

act - активность(False\True)

Устанавливает активность выбранного вида


Для работы с курсором применяется команда DCreateMouse().

На самом деле она дублирует команду DCreateWindow(), но сделана для удобства.

Обновление же курсора осуществляется общими командами(работа с фреймами).

Пример

Include "D_GUI2.bb"

Graphics3D 800,600,32,2

SetBuffer BackBuffer()

ClearTextureFilters()

cam = CreateCamera()

InitGUI()

Mouse = DCreateMouse(36,36,"Mouse.png",12)

Repeat

DUpdateFrame Mouse

DPositionFrame Mouse, MouseX(), MouseY()

RenderWorld()

Flip

Until KeyHit(1)

DFreeGUI()

End


DCreateMouse%(width%, height%, image$, frame% )

width%, height% - ширина и высота рисунка курсора

image$ - файл рисунка курсора

frame% - кол-во фреймов курсора (для анимированных фреймов)

Создает фрейм-курсор.


Для работы с битмап-текстом необходимо сначало загрузить шрифт. Это делается с помощью команды DLoadFont()

Формат шрифтов рекомендуется применять png или tga(для отображения прозрачности).

Размер шрифта пока поддерживается лишь 512х512.

Пример

Include "D_GUI2.bb"

Graphics3D 800,600,32,2

SetBuffer BackBuffer()

ClearTextureFilters()

cam = CreateCamera()

InitGUI()

Font.TFont = DLoadTFont("font.png")

Txt = DCreateText(Font, 10, 10, "Hello world!!!", 0.7)

Repeat

RenderWorld()

Flip

Until KeyHit(1)

DFreeGUI()

End


DLoadFont%( fontfile$)

fontfile$ - файл битмап-шрифта.

Загрузить шрифт.


DFreeFont%(Font.TFont)

Font.TFont - объект битмап шрифта типа TFont

Удалить шрифт.


DFreeAllFont()

Удалить все шрифты.


Перед работой удостоверьтесь что у вас есть XML.BB. Он должен лежать в той же папки что и сам ГУИ

Первое что надо - это создать саунд-лист. Он представляет собой xml-файл.

Утилита для составления саунд-листов поставляется в комплекте с гуи (SoundList).

Описание категорий звуков

В зависимости от категории файл используется для:

click - звук для озвучки нажатия на фрейм

over - звук для озвучки наведения курсора на фрейм

keyboard - звук для озвучки ввода текста в EditBox

music - фоновая мелодия(пока не используется)

move - звук при движении фрейма

turn - звук при вращении фрейма

В зависимости от категории звука он сам играется в нужный момент.

После создания саунд-листа надо его загрузить. Это делается командой DInitSound(файл_саунд_листа).

Чтобы его загрузить для определленного фрема пишем:

DSetSound(фрейм, ID_звука)

Пример

Include "D_GUI2.bb"

Graphics3D 800,600,32,2

SetBuffer BackBuffer()

ClearTextureFilters()

cam = CreateCamera()

InitGUI()

DInitSound("soundList.xml")

frame = DCreateFrame(100,100,"")

DSetSound(frame, "Click1") ;Так как этот звук имеет катигорию "click",

;он будет играться при клике

DSetSound(frame, "Over1") ;Так как этот звук имеет катигорию "over",

;он будет играться при наведении курсора на фрейм

Repeat

DActiveBtn(frame, 0,0,0,100,255,100)

RenderWorld()

Flip

Until KeyHit(1)

DFreeGUI()

End


DInitSound%(file_list_sound$)

file_list_sound$ - файл саунд-листа.

Загрузить звуки из саунд-листа.


DSetSound%(ID_sound$)

ID_sound$ - идентификатор звука.

Установить звук для фрема.


DGetSound%(ID_sound$)

ID_sound$ - идентификатор звука.

Получить звук из саунд-листа.


DFreeAllSounds()

Удаляем все звуки.


Константы используемые в модуле:

DGUI_ENTORDER - максимальный ордер. Все элементы будут иметь ордеры меньше данного. Стандартно используется значение -500.

DGUI_CAMERA - камера вашего gui-интерфейса.

DGUI_CAMPIVOT - пивот к которому крепятся все элементы.

DGUI_VIEWX, DGUI_VIEWX - вью порты.